***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 04, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt RB751V-40-AU A K 
.param
+vc0 = 4.558e-3
+vc1 = 1.012e-4
+vc2 = 2.753e-5
+tc1 = 9.057e-2
+tc2 = 4.363e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3   
+is = 3.356e-9
+n = 1.022
+rs = 2.553
+ikf = 6.522e-3
+bv = 44
***** capacitance parameter ***
+cjo = 3.552e-12
+vj = 3.905e-1
+m = 3.711e-1
+fc = 0.5  
***** temperature coefficient ***
+tnom = 25                 
+eg = 6.822e-1
+xti = 3 
+tikf = -6.557e-3
+trs1 = -6.772e-3
+trs2 = 9.878e-6
.ends RB751V-40-AU
*$
